Allt om Lotus Notes & Domino

• Specificera vilken agent du vill processa
• Hämta agenten och lägg den i en notesnotecollection
• Exportera agenten som XML (DXL)
• Tala om Lotusscript att vi vill processa xmlkoden enligt DOM
• Vänta till processen att använda DOM är klar
• Ändra eller skapa de noder i xmlträdet som styr scheduleringen
• Importera den förändrade XML/DXL koden för agenten till databasen igen (via s.k. pipelining)
• Signera och spara agenten.

Declarations

Dim AgentName As String
Dim AgentType As String
Dim AgentHour As String
Dim agentMinute As String
Dim AgentRunOnServer As String
Dim AgentRunOnWeekends As String

Sub Initialize
	
	' http://www.notessidan.se
	
	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim domparser As notesdomparser
	Dim exporter As NotesDXLExporter
	Dim importer As notesDXLImporter
	Dim doc As notesdocument
	Dim nc As NotesNoteCollection
	Dim agent As notesagent
	
	' Sätt agentschedulering
	AgentName = "Dummy"
	AgentType = "byminutes"	
	AgentHour = "2"
	AgentMinute = "10"
	AgentRunOnServer = "local"
	AgentRunOnWeekends = "true"
	
	Set db = session.CurrentDatabase
	
	' Hämta agenten och lägg den i nc
	Set agent = db.GetAgent(AgentName)
	Set nc = db.CreateNoteCollection(False)
	Call nc.Add(agent)
	
	' Exportera agenten som xml
	Set exporter = session.CreateDXLExporter(nc)
	
	' Se till så att vi kan processa xml:et via xmlklasserna i Notes
	Set domParser  = session.CreateDOMParser(exporter)
	
	'Tigga ProcessDom när domParsen är klar
	On Event PostDOMParse From domParser Call ProcessDOM
	
	' Importera in de förändringar vi gjort i ProcessDom in i databasen igen
	Set importer = session.CreateDXLImporter(domparser, db)
	importer.DesignImportOption = 6
	Call exporter.process
	
	' Signera och spara den ändrade agenten
	Set doc = db.GetDocumentByID(nc.GetFirstNoteId)
	Call doc.Sign()
	Call doc.save(False,False)
	
End Sub

Sub ProcessDom(domParser As NotesDOMParser) 
	
	' http://www.notessidan.se
	
	Dim rootnodelist As NotesDOMNodeList
	Dim agentnodelist As NotesDOMNodeList
	Dim triggernode As NotesDOMElementNode
	Dim agentnode As NotesDOMElementNode
	Dim domdoc As NotesDOMDocumentNode
	Dim newnode As notesdomelementnode
	Dim newnodelist As notesdomnodelist
	
	'Processa XML
	Set domDoc = domParser.Document
	Set rootnodeList = domDoc.GetElementsByTagName("agent")
	
	For i = 1 To rootnodeList.NumberOfEntries
		Set agentNode = rootnodeList.GetItem(i) 
		If agentnode.GetAttribute("name") = AgentName Then
			Set agentnodelist = agentNode.GetElementsByTagName ("trigger")
			Set triggernode = agentnodelist.GetItem(1)
			Call triggernode.SetAttribute("type","scheduled")
			Set newnodelist = triggernode.GetElementsByTagName("schedule")
			
			' Kolla ifall typ schedule redan finns
			If newnodelist.NumberOfEntries > 0 Then
				Set newNode = newnodelist.GetItem(1)
			Else
				Set newnode = domdoc.CreateElementNode("schedule")
			End If
			
			' Ersätt eller skapa nya attribut
			Call newnode.SetAttribute("type",AgentType)
			Call newnode.SetAttribute("hours",AgentHour)
			Call newnode.SetAttribute("minutes",AgentMinute)
			Call newnode.SetAttribute("runlocation",AgentRunOnServer)
			Call newnode.SetAttribute("onweekends",AgentRunOnWeekends)
			Call triggernode.appendchild(newnode)
			
		End If
	Next	
	domParser.Serialize
	
End Sub