Allt om Lotus Notes & Domino

Sub Initialize
	
	' Detta skript gör ett moln av taggar baserat på kolumn 1 i en vy
	' dvs om du har dina taggar/kategorier i ett fält så kategorisera detta 
	' fältet i första kolumnen.
	
	On Error Goto e
	Dim entry As notesviewentry, nav As notesviewnavigator,view As notesview
	Dim db As notesdatabase,diff As Integer,max As Integer,min As Integer
	Dim pub As Integer,session As New notessession,wdb As Variant
	
	Set db = session.currentdatabase
	Set view = db.getview("MinVy")
	Set nav = view.CreateViewNav
	wdb = Evaluate(|@WebDbName|)
	
	Set entry = nav.GetFirst
	Do Until entry Is Nothing
		If entry.ChildCount > max Then max = entry.childcount
		Set entry = nav.GetNextCategory(entry)	
	Loop
	
	min = 1
	diff = max - min
	pub = diff / 3
	
	Print |<div style=width:200>|
	
	Set entry = nav.GetFirst
	Do Until entry Is Nothing
		
		Select Case entry.childcount
		Case min : Print |<span style=font-size:10px>|
		Case max : Print |<span style=font-size:20px>|
		Case Is > min + (pub *2) :Print |<span style=font-size:18px>|
		Case Is > min + (pub) :Print |<span style=font-size:16px>|
		Case Else : Print |<span style=font-size:12px>|
		End Select
		
		Print |<a href=/| + wdb(0) + |/ByCat?Openview&type=Blogg&cat=| + _
		entry.ColumnValues(0) + |>| + entry.ColumnValues(0) + |</a>|
		Print |</span>|
		Set entry = nav.GetNextCategory(entry)
	Loop
	
	Print |</div>|
	Exit Sub
e:
	Print  Error,Erl
End Sub